#!/usr/bin/perl

#
#   Create an SVG file that displays a gradient-histogram of file sizes
#   for a given directory and its subdirectories.
#
#   The SVG goes to standard output.
#
#   Copyright (C) 2002 J. David Eisenberg under GPL
#
use warnings;
use strict;

use File::Find;

my @file_sizes;     # array of file sizes
my $total_files;    # number of files in directory and subdirectories
my $max_file_size;  # maximum file size


if (scalar @ARGV != 1)
{
    print "Create SVG diagram showing file size ",
        " distribution for a directory\n";
    print "Usage: $0 directory\n";
    exit(0);
}

$total_files = 0;
$max_file_size = 0;
find(\&accumulate, $ARGV[0]);

#
#   Create the header of the SVG file
#
print <<"SVG_HEAD";
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE svg PUBLIC "-//W3C//DTD SVG 1.0//EN"
    "http://www.w3.org/TR/2001/REC-SVG-20010904/DTD/svg10.dtd">

<svg width="700px" height="80px"
    viewBox="0 0 700 80"
    preserveAspectRatio="xMinYMin meet">

    <title>File sizes for $ARGV[0]</title>
    <desc>
        Distribution of file sizes
        of $ARGV[0] and its  subdirectories
    </desc>

<defs>
<g id="empty-bar">
   <rect x="-0.5" y="19.5" width="601" height="21"
      style="fill: none; stroke: black;"/>
</g>

<g id="gray-dividers"
   style="stroke: gray; fill: none;
   stroke-width: 0.5;">
   <path d="M 60 20 v 20
      M 120 20 v 20
      M 180 20 v 20
      M 240 20 v 20
      M 300 20 v 20
      M 360 20 v 20
      M 420 20 v 20
      M 480 20 v 20
      M 540 20 v 20"/>
</g>
</defs>
SVG_HEAD

my $size;       # size of an individual file
my $i;          # the ubiquitous loop counter
my $x;          # x-offset of a size range
my $pct_count;  # % of files in a range
my $hue;        # amount of blue;
                # equal to 100 - file percentage
my @slots;      # number of files in each range

#
#   figure out how many files are in
#   each percent of the range of file sizes
#
foreach $size (@file_sizes)
{
   $pct_count = int(100 * $size/$max_file_size);
   if ($pct_count == 100)
   {
      $pct_count = 99;
   }        
   $slots[$pct_count]++;
}

print qq!<g transform="translate(10, 15)"\n!;
print qq! style="font-size: 6;">\n!;
print qq!\t<text x="0" y="15" !,
      qq!style="font-size: 12px;">\n!;
print qq!\t\t$ARGV[0] ($total_files files)\n!;
print qq!\t</text>\n!;

for ($i=0; $i < 100; $i++)
{
   next if (!$slots[$i]);
   $hue =
      90 - int(100 * $slots[$i]/$total_files);
   if ($hue < 0 )
   {
      $hue = 0;
   }
   $x = $i * 6;

   # display the rectangle  
   print qq!\t<rect x="$x" y="20" !,
         qq!width="6" height="20"\n!;
   print qq!\t\tstyle="fill: !,
         qq!rgb(${hue}%, ${hue}%, 100%);"/>\n!;

   # fill in the text
   if ($slots[$i] < 10)
   {
      print
         qq!\t<text x="!, $x+3, qq!" y="34" !,
         qq!style="text-anchor:middle; fill: !,
         ($hue < 30) ? "white" : "black",
         qq!;">$slots[$i]</text>\n\n!;
   }
   else
   {
      print
         qq!\t<text x="!, $x, qq!" y="34" !,
         qq!textLength="5" !,
         qq!lengthAdjust="spacingAndGlyphs"\n!,
         qq!\t\t!,
         qq!style="fill: !,
         ($hue < 30) ? "white" : "black",
         qq!;">$slots[$i]</text>\n\n!;
   }
}

print qq!\t<use xlink:href="#empty-bar"/>\n!;
print qq!\t<use xlink:href="#gray-dividers"/>\n!;

#
# put labels beneath the bar
#
print qq!\t<g style="font-size: 10px; !,
   qq!text-anchor:middle;">\n!;


#
#   the zero label
#
print qq!\t\t<text x="0" y="50">!;
print "0";
print qq!</text>\n!;

#
#   the middle label
#
print qq!\t\t<text x="300" y="50">!;
print int($max_file_size/2048), "k";
print qq!</text>\n!;

#
#   the end label
#
print qq!\t\t<text x="600" y="50">!;
print int($max_file_size/1024), "k";
print qq!</text>\n!;

print qq!\t</g>\n!; # ends labeling

print qq!</g>\n!; # ends graph

print "</svg>\n";

sub accumulate
{
   my @info;

   if (-f $_)
   {
      @info = stat($_);
      push @file_sizes, $info[7];
      if ($info[7] > $max_file_size)
      {
         $max_file_size = $info[7];
      }
      $total_files++;
   }
}